AutoHotkey スレッド part7

AutoHotkey スレッド ..

2:名無しさん＠お腹いっぱい。
08/12/31 12:41:04 ROX9gd900
■関連記事のあるサイト

AutoHotkey メモ - Principia
URLﾘﾝｸ(principia.s54.xrea.com)
AutoHotKey - notitle.txt
URLﾘﾝｸ(kan.s151.xrea.com)
なまず日記
URLﾘﾝｸ(www.tierra.ne.jp)
eamatの日記
URLﾘﾝｸ(d.hatena.ne.jp)
おばけ日記
URLﾘﾝｸ(d.hatena.ne.jp)

1 Hour Software by Skrommel - DonationCoder.com
URLﾘﾝｸ(www.donationcoder.com)
ACConsole
URLﾘﾝｸ(www.autohotkey.com)
Tips N Tricks(公式フォーラムのトピック)
URLﾘﾝｸ(www.autohotkey.com)

3:名無しさん＠お腹いっぱい。
08/12/31 12:41:35 ROX9gd900
FAQ
Q：CapsLock(英数)キーの割り当てがうまくいかないよ
A：日本語環境だとLock系キーの動作は不定。
　 OS側がキーUp/Down情報が正しく返してこないので対処のしようがない。
　 OSのローカライズ段階で発生してる問題なので、窓使いの憂鬱やChange Keyのように
　ドライバレベルで弄らないとダメだが英語圏では問題ないらしいので今後のサポートもあまり期待できない。
　対処としては前述のソフトで、CapsLock（英数）キーを別のキー（F13～F24など）に割り当ててから
　 AHKで利用すべし。

Q：「～ＡチЯ㌔荏柿義形港餐汁秦疏蛋伝覗描冒輿倭兪啻嫣彖拜杼歔」を含む文字列がうまく扱えないよ
A：これらの文字の2バイト目が、AHKのエスケープ文字である0x60[`]なため。
　対処としてはこれらの文字の"直後"に「`」を記述する（例：「線形`代数」）か、
　 #EscapeCharでエスケープ文字を別のものに変えるべし。

4:名無しさん＠お腹いっぱい。
08/12/31 12:42:53 ROX9gd900
Q：Shift, Ctrl, Alt, Winキー以外のキーを修飾キーとしてキー割り当てしたいよ
　（例：無変換 + IKJLキーをそれぞれ「↑↓←→」に割り当てたいよ）など
A：Remap機能は記述が簡単になる反面、細かい指定がしにくい。
　流行らせるページのHotkeys, キーリスト, リファレンス→Send, #IfWinActive, GetKeyState()なども参照すること。
　なお、例の場合は以下のように記述する。
　 sc07B & I:: Send, {Blind}{Up}
　 sc07B & K:: Send, {Blind}{Down}
　 sc07B & J:: Send, {Blind}{Left}
　 sc07B & L:: Send, {Blind}{Right}

※ いくつかのエディタについてははキーワード定義が以下に添付されているので参考に。
　　{AutoHotkeyのインストールフォルダ}\Extras\Editor

5:名無しさん＠お腹いっぱい。
08/12/31 13:01:29 ROX9gd900
勝手に追加FAQ?

Q: GUI作るのめんどくせ～～
A: 公式( URLﾘﾝｸ(www.autohotkey.com) )から SmartGUI Creator をDLして使え

Q: ファイルパスに駄目文字があるんだが、、、
A: 駄目文字微対策版( URLﾘﾝｸ(yak.myhome.cx) )を使え。

Q: 「XX hotkeys have been received in the last XXXXms.」って怒られるんだけど、、、(XXは環境による)
A: 多分自分自身のキーを送って無限ループになっている。例) 「a::Send, a 」
　先頭に $ を付ければ回避できる(NT系のみ)。例) 「$a::Send, a」

Q: AHKってマルチスレッドじゃないの？
A: 「擬似マルチスレッド」です。最後に割り込んだスレッドが終わるまで元スレッドは動きません。

> 要は処理系統が複数同時に走らないってこと。図にするとこんな感じ。
> → 実行中、 …: 割り込み終了待ち
>　元スレッド　　　→→→→→→→→→→→……………………………………→→→→
>　　　　　　　　　　　　　　　　　　　　　　　　　　　★割込　　　　　　　　　　　　　　　　↑再開　　　　
>　割り込みスレ　　　　　　　　　　　　　　　　　　→→→→…………→→→→→→END
>　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　◆割込　↑再開
>　更に割り込み　　　　　　　　　　　　　　　　　　　　　　　　→→→END

6:名無しさん＠お腹いっぱい。
08/12/31 13:48:04 nnSK+Aaz0
Q: 完璧なスクリプトなのに、なぜerrorが出るの？
A: （文頭に）全角スペースを使ってませんか？目に見えないものもあります。

Q: 作りたいんですけど？どうすればいいのでしょうか？ご教示頂きたいです。よろしくお願いします。
A: ご勝手に。簡単ですから（メモ帳等を使い）自分で書いてください。
　　ここの住人は親切ですが、それはある程度努力してきたからです。
　　主人でも客人でもなく、努力も見えない貴方の命令には従えません。

Q: それでも作りたいんですけど？
A: 題材によっては、期待以上のスクリプトが出現する可能性もあります。

7:名無しさん＠お腹いっぱい。
08/12/31 14:11:09 nnSK+Aaz0
Q: 具体的に何が出来ますか？どこにありますか？
A: マウスジェスチャ、ThumbRemap、TTBaseプラグインの数種、仮想デスクトップ等
　　　１: 「AutoHotkeyを流行らせるページ」の「My Scripts」や「BBS」の投稿スレ
　　　２: 公式のWiki「Compilations」

8:名無しさん＠お腹いっぱい。
09/01/02 11:43:21 3YMBcArZ0
AかつB、かつ更にCまたはD。の時のif文はどう書きますか？
if A && B
if C or D
という風に書いているけど、１文で書けたらスマートだと思うんだけど。

9:名無しさん＠お腹いっぱい。
09/01/02 16:30:57 dpIHoV0B0
if (a && b) && (c || d)

10:名無しさん＠お腹いっぱい。
09/01/02 17:14:38 dpIHoV0B0
新春 Mini Tips
■ ヒアドキュメント

文字列をメタキャラ(`t や `n など)を用いずに定義できる
※ 必ず行頭に ( ) が無ければならない。

; = 演算子での文字列代入。かなり楽ちん。%hoge% とすれば変数参照も出来る。
str1 =
(
aaa = %aaa%
bbb = %bbb%
)

; := 演算子でも利用できる

str2 := "
(
aaa = " . aa . "
bbb = " . bb . "
)"

;変態的な利用方法
MsgBox, % "
(
ああ = " aa "
いい = " bb "
うう = " cc "
)"

11:名無しさん＠お腹いっぱい。
09/01/02 17:19:37 dpIHoV0B0
■簡易オンスクリーンディスプレイ(OSD)関数・・・全角スペースを Tab に変えること！
OSD_Msg(title, msg, dur, pos="BL", fc="Aqua", fs1=28, fs2=36) {
　global Progress2 ; タイマで呼ぶラベルは static 変数は見えないので
　static _fs1,_fs2,_fc,_pos
　if (pos != _pos || fc != _fc || f1 != _f1 || f2 != _f2)
　　Progress2 := false
　if (!Progress2) {
　　Process, Exist
　　MyPid := ErrorLevel
　　opt:=InStr(pos, "L") ? "C00" : ""
　　w := A_ScreenWidth,　h := fs1 + fs2 + 40
　　x := A_ScreenWidth - w, y := InStr(pos, "B") ? A_ScreenHeight-(h+30) : InStr(pos, "M") ? Round((A_ScreenHeight-h)/2) : 10
　　Progress, 2:Hide B x%x% y%y% w%w% h%h% CW000001 CT%fc% ZH0 ZW0 ZY0 ZX0 FM%fs1% FS%fs2% WM1000 WS1000 %opt%, %msg%,%title%,%A_ThisFunc%
　　DetectHiddenWindows, On
　　WinGet, hwnd, ID, %A_ThisFunc% ahk_class AutoHotkey2 ahk_pid %MyPid%
　　WinSet, TransColor, 000001, ahk_id %hwnd%
　　WinGetPos, ,,,h, ahk_id %hwnd%
　　WinMove, ,%y%,,,ahk_id %hwnd%
　}
　Progress2 := true
　Progress, 2:,%A_Space%%msg%%A_Space%,%title%
　Progress, 2:Show
　_fc := fc,_fs2:=fs2,_fs1:=fs1,_pos:=pos
　SetTimer, OSD_Msg_Off, -%dur%
　return
　OSD_Msg_Off:
　　Progress2 := false
　　Progress, 2:Off
　　return
}

12:名無しさん＠お腹いっぱい。
09/01/02 17:21:35 dpIHoV0B0
※ Progressを利用するので、GUIを消費しない。時計表示などにいいかも。
※ 文字列以外の引数が変わると再初期化する。文字だけ変わる場合はちらつかない。

title : タイトル文字列
msg：メッセージ文字列
dur:　表示時間(ms)
pos: 位置と配置(TL で Top Left、 BCで Bottom Center、右寄せは無いｗ)
;fc:フォント色(16進数表記でも可)
fs1:タイトルの文字サイズ,
fs2:メッセージの文字サイズ

13:名無しさん＠お腹いっぱい。
09/01/02 17:24:57 dpIHoV0B0
■ サウンドデバイスの一覧を改行区切りで得る関数
waveOut/waveIn , midiOut/midiIn に対応

複数の入出力デバイスがなければ全く意味がない。

SoundDevice_GetDeviceList(media="wave", isOut=true, requireId=false) {
　static cbxoc:=256,delim:="`n"
　uDeviceID:=0
　func := InStr(media, "wave") ? "wave" : InStr(media, "midi") ? "midi" : ""
　if (!func)
　　return
　func .= isOut ? "Out" : "In"
　VarSetCapacity(xoc, cbxoc, 0x00) ; Xoc (WAVEOUTCAPS / MIDIOUTCAPS)
　Loop {
　　result := DllCall("winmm.dll\" func "GetDevCapsA", UInt,uDeviceID, Int,&xoc, UInt,cbxoc, Int)
　　if (result == 2) ; MMSYSERR_BADDEVICEID
　　　break
　　if (result == 0) { ; MMSYSERR_NOERROR
　　　devName:=""
　　　list .= StructGetString(xoc, 8) ; WAVEOUTCAPS と MIDIOUTCAPSのデバイス名称までは構造が同じ
　　　　. (requireId ? ("`t" uDeviceID) : "")
　　　　. delim
　　}
　　uDeviceID++
　}
　StringTrimRight, list, list, % StrLen(delim)
　return list
}

14:名無しさん＠お腹いっぱい。
09/01/02 17:27:03 dpIHoV0B0
■ WaveOutを指定のデバイスIDで変更する
>>13 と組み合わせて使う。

SoundDevice_SetWaveDeviceId(id) {
　static WAVE_MAPPER:=-1, MMSYSERR_NOERROR:=0
　dwPreferedID:=0, dwUsePreferedOnly:=0
　if (MMSYSERR_NOERROR == DllCall("winmm.dll\waveOutMessage", UInt,WAVE_MAPPER, UInt,0x2015, UInt,&dwPreferedID, UInt,&dwUsePreferedOnly, Int)) {
　　ret := DllCall("winmm.dll\waveOutMessage", UInt,WAVE_MAPPER, UInt,0x2016, Uint,id, dwUsePreferedOnly, Int)
　　return true
　}
　return false
}

15:名無しさん＠お腹いっぱい。
09/01/02 17:31:07 dpIHoV0B0
■ 現在選択されているWave再生デバイス名を取得する
SoundDevice_GetDeviceName() {
　RegRead, Playback, HKEY_CURRENT_USER, Software\Microsoft\Multimedia\Sound Mapper, Playback
　return Playback
}
■ 名前でWave再生デバイスを指定する (>>13-14 と組み合わせで使う)
SoundDevice_SetDeviceName(deviceName) {
　deviceList := SoundDevice_GetDeviceList("wave", true, true)
　Loop, PARSE, deviceList, `n
　{
　　StringSplit, data, A_LoopField, %A_Tab%
　　if (data1 == deviceName)
　　　return SoundDevice_SetWaveDeviceId(data2)
　}
}
■ 再生デバイスのトグルをする。上のものと組み合わせて使う。
　戻り値に変更後のデバイス名を返す
SoundDevice_ToggleDevice() {
　currentDeviceName := SoundDevice_GetDeviceName()
　deviceList := SoundDevice_GetDeviceList()
　StringSplit, device, deviceList, `n
　deviceCount:=device0, currentId:=0, nextId:=1
　Loop, %deviceCount%
　　if (device%A_Index% == currentDeviceName)
　　　currentId := A_Index
　　else if (currentId && A_Index == (currentId + 1))
　　　nextId := A_Index
　SoundDevice_SetDeviceName(device%nextId%)
　return device%nextId%
}

16:名無しさん＠お腹いっぱい。
09/01/02 17:57:57 YhIzrby/0
>>10-15
新春早々為になるテク乙です

17:名無しさん＠お腹いっぱい。
09/01/02 20:00:09 3YMBcArZ0
>>9
㌧。考えてみたらそりゃそうかorz
小中学生レベルだｗ

18:13
09/01/02 20:30:59 dpIHoV0B0
>>13 で使う関数が抜けていた orz

StructGetString(ByRef pSrc, offset=0) {
　Loop 0xffff {
　　char := NumGet(pSrc, offset, "Char")
　　offset++
　　if (!char)
　　　break
　　buff.=Chr(char)
　}
　return buff
}

19:13
09/01/02 20:35:02 dpIHoV0B0
連投ｗ

■ あいている GUI 番号を探す。 asc=true：昇順(1から探す) / false: 降順(99から探す)
まぁあんまり使わないけど、色々GUI作っている人はどうぞ

GuiFindFreeNo(asc=true) {
　Loop, 99 {
　　guiNo := asc ? A_Index : 100 - A_Index
　　Gui, %guiNo%:+LastFoundExist
　　if (!WinExist())
　　　return guiNo
　}
}

20:13
09/01/02 20:44:24 dpIHoV0B0
■ 無理やり GUI で InputBox。(一応....モーダル）

MsgBox, % GuiInputBox("いんぷっとボックス", "何か入れてよ")
exitApp

GuiInputBox(title, message, defaultValue="") {
　DialogString := ""
　len := StrLen(defaultValue)
　len := (len < 400) ? 400 : len
　Gui, 99:default
　Gui, +ToolWindow
　Gui, Add, Text, , %message%
　Gui, Font, s12, MS Gothic
　Gui, Add, Edit, -Multi w%len%, %defaultValue%
　Gui, Add, Button, defaultValueault g99GuiClose, OK
　Gui, 99:Show,, %title%
　WinWaitClose, %title%
　return DialogString
　99GuiClose:
　　Gui, 99:default
　　GuiControlGet, DialogString, ,Edit1
　　Gui, Destroy
　　return
　99GuiEscape:
　　Gui, Destroy
　　return ""
}

21:名無しさん＠お腹いっぱい。
09/01/02 20:49:49 QykMUcBv0
せっかくのところ申し訳ないが、ニーズがあるのか微妙な内容は、
自分のブログかなんかでやってくれないか

22:13
09/01/02 20:51:04 dpIHoV0B0
■ 指定時間(ms単位)だけツールチップを表示する

#Persistent
AutoHideTooltip("このツールチップは5秒で消えます", 5000)

AutoHideTooltip(msg, dur,x="",y="") {
　Tooltip, %msg%,%x%,%y%,20
　SetTimer, AutoHideTooltip_HideTip,-%dur%
　return
　AutoHideTooltip_HideTip:
　　Tooltip,,,,20
　return
}

23:名無しさん＠お腹いっぱい。
09/01/02 20:55:16 dpIHoV0B0
わりぃ

24:名無しさん＠お腹いっぱい。
09/01/02 21:43:40 ydcUNeZl0
いや、もっとやって

25:名無しさん＠お腹いっぱい。
09/01/03 03:02:16 dU2pkIlN0
F1::
hogehoge
sleep,5000
return

F1::
hogehoge2
sleep,10000
return

と指定して f1のsleepの間はf2を押しても無視するようにしたいです。
変数使ってifでreturnさせれば良いかなと思っていたのですが>>5をみるとf2を押すごとに割り込みが発生するみたいなのですが
よい方法はないですか？

さらに指定したキー以外の場合は押されたキーをsendしてsleep,3000するようにしたいのですが全キー分部書かないとできないでしょうか？

26:名無しさん＠お腹いっぱい。
09/01/03 03:06:05 dU2pkIlN0
ああう

F1::
hogehoge
sleep,5000
return

F2::
hogehoge2
sleep,10000
return
です。

27:名無しさん＠お腹いっぱい。
09/01/03 10:45:42 sv6+rPm90
> f1のsleepの間はf2を押しても無視するようにしたいです
タイマーかな

F1::
if (Key_F1_NG)
return
Tooltip, HogeHoge1
Key_F1_NG:=true, Key_F2_NG:=true
SetTimer, Key_F1_Enable, -5000
SetTimer, Key_F2_Enable, -5000
return

F2::
if (Key_F2_NG)
return
Tooltip, HogeHoge2
Key_F2_NG:=true
SetTimer, Key_F2_Enable, -10000
return

Key_F1_Enable:
Key_F2_Enable:
RegExMatch(A_ThisLabel, "Key_(\w+)_Enable", $)
Key_%$1%_NG=
return

28:名無しさん＠お腹いっぱい。
09/01/03 10:46:19 sv6+rPm90
> 指定したキー以外の場合は押されたキーをsendしてsleep,3000するようにしたい
面倒なら,、 Hotkey コマンドかな

Keys = a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z,0,1,2,3,4,5,6,7,8,9
Loop, PARSE, Keys, `,
Hotkey, *%A_LoopField%, SendAndSleep
return

SendAndSleep:
Send, % "{Blind}{" RegExReplace(A_ThisHotkey, "^\W","") "}"
Sleep, 3000
return

29:名無しさん＠お腹いっぱい。
09/01/03 14:26:47 CYbS+lGc0
#y::WinActivate, Untitled - Notepad
と定義している場合に Win+Yを押そうとして、
Winキーを押してYを押す前に気が変わって、
Winキーを放すとスタートメニューが表示されます。
これが鬱陶しいので表示されないようにして、
スタートメニューを開くには Win+A を使うようにはできるでしょうか？

30:名無しさん＠お腹いっぱい。
09/01/03 14:29:16 Wek1X/3L0
>>29
そもそもWinキーを割り当てること自体間違ってないか？

31:名無しさん＠お腹いっぱい。
09/01/03 15:02:04 CYbS+lGc0
>>30
Ctrl, Shift, Alt はアプリごとのショートカットと被る可能性があるので、
アプリによらないグローバルなホットキーには
Winキーを使いたいと思ってるんですが、間違ってるんでしょうか？
とすると修飾シンボルの # の存在意義は何なのでしょうか？

32:名無しさん＠お腹いっぱい。
09/01/03 15:11:50 6IxvyQ1m0
winの単独押しを殺せばいいだけじゃないの？

33:名無しさん＠お腹いっぱい。
09/01/03 15:28:57 WGxALqxL0
キーカスタマイズソフトスレで
>autohotkeyで不可能なことをkeybatでとりあえず、これを具体的に言っとけ。
って有ったので質問したらで答えられないからと，こっちに誘導されました．

AutoHotKeyでは，ネットワーク経由で別PCのキー操作って出来るのでしょうか？
一枚のキーボードで複数のPCを操作したいんです．
一部のキーだけ別PCに割り当てとかマクロ動かしたいので切換器では無理．．．

コマンドスクリプトとかも見たけどネットワーク関連は見あたらず．
ニッチな要望だから対応してないのかな，Vistaに移行できねぇorz

34:名無しさん＠お腹いっぱい。
09/01/03 15:29:59 CYbS+lGc0
>>32
ありがとうございます
LWin:: Return
#a:: Send, {LWin}
でいけたみたいです

35:名無しさん＠お腹いっぱい。
09/01/03 15:31:41 CYbS+lGc0
>>33
synergy ってソフトあるけどダメ？

36:名無しさん＠お腹いっぱい。
09/01/03 16:18:02 /iPm/dkm0
synergyはあるな

37:名無しさん＠お腹いっぱい。
09/01/03 16:42:31 7Ih2hIx60
AutoHotkeyとXkeymacsを共存して使ってる人いる？

俺の環境だと　C-s での検索がまともに動かないんだけど
うまく使えてる人いない？

38:名無しさん＠お腹いっぱい。
09/01/03 17:25:58 wjl7GfuA0
クリップボードに

<a href="URLﾘﾝｸ(www.esample.com)" alt="test.jpg" target="_blank">test.jpg</a>

という文字を入れて、

URLﾘﾝｸ(www.esample.com)

という文字だけをクリップボードに抜き出し直させる処理を書きたいんですけど

先頭の　<a href="　は、StringTrimLeft命令で先頭9文字を切り抜けばいいのは分かるのですが

その後 " alt=～　以降の文字を消す処理って、どのように書けばいいでしょうか。
( " alt=～　以降は、その時によって文字数が変わります)

39:名無しさん＠お腹いっぱい。
09/01/03 17:30:24 sv6+rPm90
正規表現

40:名無しさん＠お腹いっぱい。
09/01/03 17:36:08 sv6+rPm90
正規表現を覚えるまでもないと言うのなら、
href=" の位置を探して、それ以降に初めて出現する " を探して切り出せばいい。
(InStr()関数か、 StringGetPos 使って割り出して、SubStr()関数使う)

41:名無しさん＠お腹いっぱい。
09/01/03 19:21:44 9kdhYRBF0
LOOP, PARSE, ClipBoard, "
で回して
A_LoopFieldに「http:」があったら
適当な変数に入れて抜ければいい

42:38
09/01/03 19:36:59 wjl7GfuA0
皆さんありがとうございます。処理一つ書くにしても、いろいろな方法があるのですね。
41さんの考え方はなかったです。

40さんの教えてくれた InStr() 関数で " の位置を取得して、StringMid関数で抜き出そうと思います。
ありがとうござました。

43:名無しさん＠お腹いっぱい。
09/01/03 21:33:02 E/T17g2E0
>>27-28
ありがとうございます。
助かりました。

44:名無しさん＠お腹いっぱい。
09/01/03 21:52:54 qEZ7p5R10
ふと思い立って、OnMessageでWM_TIMERを仕込んで、
SetTimerコマンドを使った時にどういう挙動するか調べてみた。
　
で、SetTimerの数、SetTimerの時間に関わらず、
最小時間のタイマー1つしか動いてないようだった(タイマーID9)。
SetTimerコマンドで1つもタイマーを作っていないと、
WM_TIMERには飛んでこない。
　
という感じで、AHKではタイマー管理用のタイマーを
1つだけ作って管理してるみたいだね。
5000msとか長めのタイマーしか使わない場合でも
最小時間(約10ms)でタイマーが動いてしまうから、
長めのタイマー使う場合は自前でDllCall("SetTimer")
した方がいいような気がするんだけど、神経質になりすぎかな？

45:名無しさん＠お腹いっぱい。
09/01/03 23:55:12 1YuNBWZ60
あけましておめでとうございます～。今年も色々と勉強させて頂きます。

ところで前スレ1000まで行きましたか？
DAT誰かうｐしてくれると嬉しいのですが。

970までは取得してあるんですけど、旅行中でチェックする時間がなかったもので。

46:名無しさん＠お腹いっぱい。
09/01/04 00:17:55 GfdFtSPf0
>>45
つ URLﾘﾝｸ(www.dotup.org)

47:名無しさん＠お腹いっぱい。
09/01/04 00:22:37 dyR0JXVY0
>>46
素早いうｐありがとうございます～。
助かりました！！

48:名無しさん＠お腹いっぱい。
09/01/04 01:27:04 o7CXEDIT0
TrackPoint 向けユーティリティの TrackWheelをうｐ。
URLﾘﾝｸ(lukewarm.s101.xrea.com)

性懲りもなく、やってます。

- レスポンス改善がメイン(レンダリングの遅いコントロールで劇的に改善)
- スクロールバー抽出速度upと精度up。

49:名無しさん＠お腹いっぱい。
09/01/04 02:38:24 97BFjk2I0
ところで前々スレ1000まで行きましたか？
DAT誰かうｐしてくれると嬉しいのですが。

50:名無しさん＠お腹いっぱい。
09/01/04 02:41:30 XwzFKclp0
>>49
Sleep, 25200000

51:33
09/01/04 02:47:14 /TC5+4Sb0
>>35, 36
やっぱsynergyっすか，実は前試して上手く動かせなかった．．．
マクロ(簡単なので良いんだけど)とか，一部のキーだけ別PC操作したいとか
微妙にやりたいことが出来ないらしかったんで，直ぐに諦めてしまった
もう一度試してみます．レスありがと

52:名無しさん＠お腹いっぱい。
09/01/04 05:15:57 uxVSj97F0
別PCの何をどのくらい操作したいのかでも
どんなソフト使うべきか決まるよ。
vncとかsshでも済むかも知れないし。

53:名無しさん＠お腹いっぱい。
09/01/04 07:31:38 p6B3/HqS0
TrackWheelのreadmeが参考になりすぎて困るので、
Googleサイトとかでページを作って検索にひっかかるようにすると、
幸せになる人がもうちょっと増えると思うんだけども

54:名無しさん＠お腹いっぱい。
09/01/04 09:11:37 JIZG7BfL0
なんという丁寧なドキュメント・・・

55:名無しさん＠お腹いっぱい。
09/01/04 10:11:15 D35r6xpC0
>>49
つ URLﾘﾝｸ(www.geocities.jp)

56:名無しさん＠お腹いっぱい。
09/01/04 10:32:20 1GxGvmcA0
>>51
synergyよりも最近の流行はこれ
【マウス＆キーボード共有】Input Director
ｽﾚﾘﾝｸ(software板)

57:33
09/01/04 12:18:27 /TC5+4Sb0
>>52
MMORPGで二垢するときに，一台のキーボードで操作してます．
WASDで移動QEで旋回，その他キーとCtrl，Altなどの組合せで色々な機能を
普通のキーボード部分は接続してあるPCのキー入力に使い
2nd側のPC操作用に
カーソルキーを2ndPCのWASD，QEを2ndPCのDelete,PageDown
テンキーの0を2ndPCのスペースバー，1～9を2ndPCの1～9，.を2ndPCのTABなどなど
F6を押すとトグルで2ndPC側のマクロ発動(実際には3ボタン連打ｗ)してます

それだけではどうしてもまかなえないときもあるので，そのときは
キーボードとマウスを全部2ndPC操作に切り替えてます．

まー，KeyBatで出来ることで設定していったらこうなっちゃったんですが
キーボード共有ソフトだとちょっと無理で
Vistaに対応したキーカスタマイズ系だと複数PC操作出来るの無いなーと

>>56
それは面白そうなので観てきます

スレ違い気味なネタにレスありがとうございます

58:名無しさん＠お腹いっぱい。
09/01/04 12:50:39 1GxGvmcA0
えらい器用なことやってますねｗネトゲ廃人の気合の入れようは異常ｗ

59:名無しさん＠お腹いっぱい。
09/01/04 12:52:01 o7CXEDIT0
>>53
乱暴につくってみた URLﾘﾝｸ(sites.google.com)
CSS使えなくて面倒だった

60:名無しさん＠お腹いっぱい。
09/01/04 14:48:48 FFtevMUI0
おつー

61:名無しさん＠お腹いっぱい。
09/01/04 15:38:31 dyR0JXVY0
>>59
乙です
本当にすごいｗ参考になるです

62:名無しさん＠お腹いっぱい。
09/01/04 16:32:52 1GxGvmcA0
すげえ力作ｗｗ

63:名無しさん＠お腹いっぱい。
09/01/05 02:28:31 RJg40VRS0
>>48
乙
いつのまにかExcelみたいな変態ポインタも消えるようになってるし
スクロールが随分となめらかになってて(・∀・)ｲｲ!!
ただ、秀丸の分割ペイン切替がなくなったのは秀使いとしては地味にクリティカルかも。

組込みで使おうとして気になった点とか

・TW.ahkの後に関数集などのahk(行頭にreturnがないもの)を Includeしようとするとエラーになる。
　環境：WinXP SP2 AHK 1.0.47.06 (original)　行末ラベル TW_EOF: が原因ぽい。
　行頭の if (A_LineNumber != 1)ってのは組込み用対策なのかな。
　これって常に1になる (組込みで使う場合も A_LineNumberはファイルごとの行数になる)ので
　いまいち機能してないような。

・OnExitの任意指定ってなくなった？ TW_Initialize()の後に無理矢理 OnExitラベル変更してるけど
　ExitAppの前に TW_End()を突っ込んでやればOK？

・.ini/.icoを相対パスで指定した場合、基準をA_LineFileと同じディレクトリにして欲しいとか言ってみるテスト
　組込み時もデフォルト設定のままで使えるようになってると大変嬉しい

64:名無しさん＠お腹いっぱい。
09/01/05 12:47:49 RJg40VRS0
ついでにも一個要望
本末転倒だがチョン押し時の Send,{Mbutton} をヌッ殺すオプションが欲しい。
というよりタイムアウトした場合用の TW_POSTACTION が欲しい。
オートスクロールは使わないがAHKからHookかけてMbutton使いたい用途は山ほどある。

数行足すだけで済むものなので今は適当に改造して使わせてもらってますが、
更新が頻繁で追っかけるの大変になってきたので、機能として盛り込んでもらえると嬉しいなっと。

65:名無しさん＠お腹いっぱい。
09/01/05 14:08:25 K2RPyvk10
> 秀丸の分割ペイン切替がなくなったのは秀使いとしては地味にクリティカル
楽だったので組み込んだ

> 組込みで使う場合も A_LineNumberはファイルごとの行数になる
知らなかったorz。無駄だから消した

> OnExitの任意指定ってなくなった？
無くなった。でも呼ばなくても平気なはずなので、Initから外した。一応Docに追記した。

> 基準をA_LineFileと同じディレクトリにして欲しい
採用。俺も面倒だったｗ

> タイムアウトした場合用の TW_POSTACTION
既にあるよ。

URLﾘﾝｸ(sites.google.com)
- ページが大きいので分割した
- 秀丸用対応の復活(Autoでやる)
- ワーキングディレクトリをTrackWheelのあるディレクトリとした(人によってはデカい)
- IEの設定が間違ってたorz

66:名無しさん＠お腹いっぱい。
09/01/05 14:10:00 K2RPyvk10
>> タイムアウトした場合用の TW_POSTACTION
>既にあるよ。
Iniにはないので自分で書いてね、ってこと

67:名無しさん＠お腹いっぱい。
09/01/05 17:30:40 RJg40VRS0
>TW_POSTACTION
すんませんまさに望んでた通りの動作でした。
TWの外に MButton: 置いて自制御する場合と混同してました。

>>65
(・∀・)ｲｲ!!
秀の場合は HorzをScroll2に指定するといい感じ。
全般的にScrooll(つまみドラッグエミュ)は慣れてないせいか操作が難しい。
うまいことコツが掴めるようになると快適なのかな。

68:名無しさん＠お腹いっぱい。
09/01/05 20:40:49 DVBHOCyB0
SQLiteModule
version1.1
URLﾘﾝｸ(sites.google.com)
内部仕様変更だけ
Dynamic Functionはいまだ理解できず
(どんなとき使えばいいんだ？)

勝手に便乗
昔Google Page Createrで同じようなの作ったけどすぐ削除された
個人的ファイル置き場にちょうどいいかな

69:名無しさん＠お腹いっぱい。
09/01/05 21:00:13 K2RPyvk10
>>68
乙。
たとえば、、、多分 SELECT文の結果をグローバル変数の配列とかにすると思うんだけど、
その最中に Loop して結果表を1行ずつフェッチする過程があるはず、
で、その行Loop中に他の関数を呼び出してデータ処理はお願いって風に出来ればなぁ、、、と思っただけ。
グローバル変数消費しないし、他の言語では結構見るタイプ。
まぁ、↓だと10カラムしか対応できなくて格好悪いけどこんな感じ。

; モジュール側
GetSelectToCallback(db, sql, funcName) {
　Loop {
　　行取得する
　　%funcName%(rowNo, colCount, col1,col2,col3,col4,col5,col6,col7,col8,col9,col10) ; 行をそのまま渡す！
　}
}

; コールする側
LV_Delete()
GetSelectToCallback(db, "SELECT * FROM HOGE", "HogeFunc")
SB_SetText(LV_GetCount() . "件")

HogeFunc(rowNo, col1="",col2="",col3="",col4="",col5="",col6="",col7="",col8="",col9="",col10="") {
　; ダイレクトにリストビューに追加する
　LV_Add("", col1, col2, col3, col4, col5, col5, col6, col7, col8,col9,col10)
}

70:名無しさん＠お腹いっぱい。
09/01/05 21:41:20 DVBHOCyB0
>>69
これは分かりやすい

理解したけど問題は列数か
頑張ってみます

71:名無しさん＠お腹いっぱい。
09/01/06 18:24:12 RYrDeuzr0
TrackWheel はコア部分変更以来、小さく動かしてゆっくりスクロールする動作が苦手になってる感じ

>行数 = Round((移動量-動作閾値分の補正) / 動作感度)

これだと tY=2 sY=10 ($Default) のとき Yが 7以上じゃないとスクロールが発生してくれないけど
しきい値を越えたら、まずは 1行動いてくれるほうがなめらかになる感じ。
value := (value-t+s)//s
とか。

あとWindowClassやControlClassの指定は部分じゃなくて前方一致？
ContexterのリストビューがスクロールしないのでSpyで見たら
WindowsForms10.SysListView32.app32 とかいう長ったらしいコントロール名だった。

72:名無しさん＠お腹いっぱい。
09/01/06 18:54:27 w/0/pa630
TrackWheelで左右に動かすとY軸が動くようにしているのは俺だけだろうな
上下で動かすよりなんとなく楽な感じがするんだよね

73:名無しさん＠お腹いっぱい。
09/01/06 19:32:47 1sWyUvxb0
> しきい値を越えたら、まずは 1行動いてくれるほうがなめらかになる感じ
そういえば、前はそうなってたわ。 Round じゃなくて Ceil 使えばいいか

> 部分じゃなくて前方一致？
誤爆がね、ってことでCaseLessの完全一致。
ワイルドカードで *Hoge* と出来るようにするよ。

つか、さすがに流れの遅いここで、このネタでスレが埋まるのはそろそろ悪い気がしてきた。。。
ブログでもいいんだけど気軽さがなぁ...この辺使わして貰っても良いかな
URLﾘﾝｸ(lukewarm.s101.xrea.com)

74:名無しさん＠お腹いっぱい。
09/01/07 22:44:52 dP98pG5w0
横から見てるだけでもいろいろ参考になるから、このまま続けてもOKと俺は思う

75:名無しさん＠お腹いっぱい。
09/01/09 00:00:05 dZ7SwV0k0
じゃ、何人かは使っているらしいんで
URLﾘﾝｸ(sites.google.com)

[V.5]
- Altキー押下時にスクロール後にSleepする設定を加えた
- サムドラッグエミュレート抑止オプションを追加
- スクロール方法の自動判別で Scroll2 を優先するオプションを追加(V.3と同じ判定になる)
- デバッグコードが残っていたのを削除
[V.4]
- 設定しても何もなかったオプション項目に意味を持たせた
- 【重大】スクロール量の算出方式で閾値を超えた時に1行動くようにした >>73
- クラス名定義でワイルドカードで中間一致を追加 >>73

76:名無しさん＠お腹いっぱい。
09/01/10 10:56:35 Uc2zWhw/0
VistaでAutoHotkeyを使用しております｡少し質問をさせて頂きたいのですが
CCleanerをウィンドウの位置やサイズを変更するため簡単なスクリプトを
書いて見たのですが､機能しません同じパターン等で他のソフトを多数､使用して
も問題無いのですが､何が原因なのでしょうか､御存じの方宜しくお願いします｡
Run,"C:\Program Files\CCleaner\CCleaner.exe"
WinWaitActive,Piriform CCleaner
WinMove, A, , 40, 100, 1200, 900
ExitApp
以下のスクリプトでもCCleanerだけ反応ありません｡
#NoTrayIcon
^1::WinMove, A, , 40, 100, 1200, 900
^0::ExitApp
return
CCleaner - Home
URLﾘﾝｸ(www.ccleaner.com)
>>>>>>>>>>( Window Title & Class )<<<<<<<<<<<
Piriform CCleaner
ahk_class #32770

77:名無しさん＠お腹いっぱい。
09/01/10 12:08:16 xVdEkJsk0
>>76
あまり参考にならないかもしれないけど、うちの環境では問題なく動作したよ。
OS:WindowsVista
CCleaner 2.15.815

78:名無しさん＠お腹いっぱい。
09/01/10 12:16:41 RDJAsW630
>>76
俺も試してみたがちゃんと機能したよ

79:名無しさん＠お腹いっぱい。
09/01/10 12:19:13 RDJAsW630
あ、ちなみに
OS:WinXP SP3
CCleaner v2.14.750

そしてアップデートあるのに気がつきました

80:名無しさん＠お腹いっぱい。
09/01/10 12:36:32 Uc2zWhw/0
レス感謝です｡CCleaner 2.15.815で同じバージョンですね｡
先ほど眠っていたXPに同じくセットすると､此方は問題無く
起動しました｡因みにVistaのエアロはどうなってますか
私はオンオフともやはりCCleanerだけ動作しません｡
77氏は問題無くVistaでも動作と言う事は環境問題かな

81:名無しさん＠お腹いっぱい。
09/01/14 12:53:14 9ldsyH9N0
思ったより難しそうだけど、習得率はVBSとどっちが簡単ですか？

82:名無しさん＠お腹いっぱい。
09/01/14 13:54:08 QS/Psi5l0
言語仕様としてはVBSの方が整理されている。

でも、ほとんどの人がAHKを使う理由は、キー割り当てや簡易GUI構築など、
VBSでは代替できない機能が目当てだと思うんで、
「習得のしやすさ」で選ぶ二択じゃない気がする。

83:名無しさん＠お腹いっぱい。
09/01/14 14:24:04 9ldsyH9N0
ちらっと見ただけだけど、面白そうな事が出来そうだな感じだったので
難易度はどれくらいなのかなと思って
wshくらいの難易度で覚えられるならやってみたいけど
あまり本格的なものだとすぐあきらめそうだなと

84:名無しさん＠お腹いっぱい。
09/01/14 14:38:13 XsghDILe0
wsh(VBA,JavaScript)ができるなら大丈夫だろ。
俺もなんとかなってる。

むしろ、AHKはかなりDSL色が強くて非常に独自言語っぽく、
他の言語だと簡単に書けたり、どの言語も同じように書けるのに、
AHKは変な書き方しなくちゃならなかったり、ちょっとクセがある。

85:名無しさん＠お腹いっぱい。
09/01/14 15:16:28 BZ/65qiJ0
>>81
おいらも2週間前にAutoHotkeyを知ったばかりの新参だけど、
「面白そうなこと」というのが具体的に決まっているのであれば、
やってみたらいいんじゃないかな。

ちなみに、おいらは前スレで紹介されてたモールス信号スクリプトを使って和文を打てるようにしたり、
物理演算シミュレーションソフトのPhunにちょっと遊べるを機能を追加したりして遊んでる。
後者のスクリプトは下手なりにソースコード晒して公開したのにウィルスと疑われてるけどなｗ
チラ裏すまそ。

86:名無しさん＠お腹いっぱい。
09/01/14 16:33:37 9ldsyH9N0
レスありがとう

ほんとにまだちょっと見た程度なので
具体的にやりたいものが決まってるわけではないんだけど
いろいろ応用が利きそうかなと
途中で挫折しなかったらまた来てまます

87:名無しさん＠お腹いっぱい。
09/01/14 17:46:00 dEH4tJQQ0
キー置き換えっつースタンスと、バッチ代わりとか簡易GUI作成ツールとかってスタンスで
大分違いが出そう。。。

mayu+WSH(+マウ筋)から AHKに完全移行したけど、最初はキー置き換えだけしかしなかったなぁ

88:名無しさん＠お腹いっぱい。
09/01/14 19:41:53 JFwvyFAk0
mayu+AHK(非常駐スクリプト)で運用。

89:名無しさん＠お腹いっぱい。
09/01/15 01:54:28 1FFYSN/50
質問です。
右クリックを押している間、
右クリックを連打するスクリプトってどう書けばいいんでしょうか？

If Rbutton
loop
{
click,rbutton
sleep, 100
}

試行錯誤してもこの程度しかわかりませんでした。
押し下げ状態とかの記述とかも流行らせるを見てもよくわかりません。
よろしくお願いします。

90:名無しさん＠お腹いっぱい。
09/01/15 02:33:30 kckjR1IW0
４と出る筈が、何で13になるの？
ichi:=1
tasu:=+
san:=3
msgbox,% ichi tasu san
return

91:名無しさん＠お腹いっぱい。
09/01/15 02:38:56 FprEOzFe0
>>90
演算子って変数に代入できるのか？

92:名無しさん＠お腹いっぱい。
09/01/15 02:50:21 7aT1UIeA0
> ichi tasu san
は、
文字列結合してを出力しろっていってるのと同じ、
つまり↓
> ichi . tasu . san
または
> %ichi%%tasu%%san%

javascript の eval とか python の　exec に相当するのってahkには無い・・・はず

93:名無しさん＠お腹いっぱい。
09/01/15 03:31:06 kckjR1IW0
>>92
Σ(ﾟдﾟ|||)ｶﾞｰﾝよく分かりました

>>91
msgbox, % ichi + san
なら4になるのに。

dynamic function calling　(1.0.47.06)でどうにかならない？

94:名無しさん＠お腹いっぱい。
09/01/15 12:53:57 zBxweuAX0
>>89
RButton::
Loop
{
If(!GetKeyState("RButton","P"))
Break
MouseClick, RIGHT
Sleep, 100
}
Return
　
>>93
Eval関数
URLﾘﾝｸ(www.autohotkey.com)

95:名無しさん＠お腹いっぱい。
09/01/15 13:05:17 1FFYSN/50
>>94
ありがとう！！

96:名無しさん＠お腹いっぱい。
09/01/15 14:48:14 XSOAc2jv0
>>94
eval良いね

97:名無しさん＠お腹いっぱい。
09/01/15 19:56:10 xL6BrQlZ0
とあるゲームで、キーにマウス移動＋クリックという作業を割り当てたのですが
sendplayをやろうとすると反応しなくなります。ちなみにOSはvistaで下のようなやつです

send play
a::
BlockInput, mousemove
send,{a Down}
send,{a up}
sleep,100
mousemove,0,0
click
sleep,100
mousemove,0,0
click
BlockInput, mousemoveoff

98:名無しさん＠お腹いっぱい。
09/01/15 20:52:43 mcfS5KF00
一行目は SendMode Play じゃないの？

それから「とあるゲーム」じゃ、色んなSendModeでやってダメなら、あきらめろとしか言えないと思うが

99:名無しさん＠お腹いっぱい。
09/01/15 23:19:11 kckjR1IW0
>>94
ありがとう(*ﾟ∀ﾟ)=3

100:名無しさん＠お腹いっぱい。
09/01/16 15:59:07 9TC51kow0
ある座標値にあるウィンドウのウィンドウハンドルを取得するにはどう書けばいいんでしょうか？

101:名無しさん＠お腹いっぱい。
09/01/16 17:07:00 ys4XQ/JO0
WinGetのcmdにListを指定して全てのハンドルを取得して、
ループでWinGetPosして判定すればいいんじゃね

102:名無しさん＠お腹いっぱい。
09/01/16 17:55:22 8WDRn3Rn0
WindowFromPointをdllcall

103:名無しさん＠お腹いっぱい。
09/01/17 15:23:11 15HQKhST0
Windowsキーが長押しかどうか判定するために
URLﾘﾝｸ(www.autohotkey.com)
のMorseを使って下のようにしても、"1"が返ってくることがありません。
LWin以外のaとかなら、ちゃんと長押しで"1"が返ってきます。
Windowsキーが長押しされたかどうか判定するにはどうすればいいでしょうか？

LWin::
p := Morse()
MsgBox, %p%
Return

104:名無しさん＠お腹いっぱい。
09/01/17 16:36:46 AAdcRplY0
LWin::MsgBox, % "long = " . LongPress(A_ThisHotkey, 500)

LongPress(key, limit) {
Loop
if !GetKeyState(key, "P")
break
return A_TimeSinceThisHotkey > limit
}

105:名無しさん＠お腹いっぱい。
09/01/17 17:35:30 CwKiW6jb0
>>103
(Pert6 >>782より転載)
これを改造すればいいよ。

782 ：名無しさん＠お腹いっぱい。：2008/11/27(木) 01:43:58 ID:pOwnMABe
よく分からんけど、 Ctrl とかが押しっぱなしになる。解決はよく分からんが対処法としてアラートだすようにした。
if書きたくないから、三項演算子だいすきif書きたくないから、三項演算子だいすき

#SingleInstance
#Persistent
keys = Ctrl|Shift|Alt|LWin|RWin
alertDur = 3000 ;(ms)
SetTimer, Alerter,200
return
Alerter:
alert =
Loop, PARSE, keys, |
{
%A_LoopField% := !GetKeyState(A_LoopField) ? 0 : !%A_LoopField% ? A_TickCount : %A_LoopField%
alert .= (%A_LoopField% && (A_TickCount - %A_LoopField%) > alertDur) ? "[" A_LoopField ": " (A_TickCount - %A_LoopField%) "ms]" : ""
}
Tooltip, %alert%
return

106:名無しさん＠お腹いっぱい。
09/01/18 23:50:13 XmkZ8Jyg0
>>104 >>105
遅くなりましたがありがとうございます。

>>104 を試してみましたが、>>103 と同じように
LWinでは長押ししても "0" しか返ってきませんでした。
LWin じゃなくて a ならばちゃんと長押しで "1" が返るんですが、
私の環境だけでしょうか？それとも LWin は特別なんでしょうか？

>>105 はよくわからないところもあって改造はできてませんが、
GetKeyState で判定して時間を計るという点では一緒なのかなと・・・

107:名無しさん＠お腹いっぱい。
09/01/18 23:58:42 svY9DCGD0
>>101-102

お礼が送れて本当にすみませんでした。ﾚｽありがとうございました　
DllCall("WindowFromPoint", Int, X, Int, Y, UInt)

で、コントロールのウィンドウハンドルを取得できる事まで分かったのですが
ここからウィンドウを取得するにはどうしたらいいのでしょうか・・・？

108:名無しさん＠お腹いっぱい。
09/01/19 00:02:32 U3VSUvzG0
正解出してやってんのに馬鹿じゃねーの

109:名無しさん＠お腹いっぱい。
09/01/19 17:56:30 Qrvr5YD20
日付の計算で2009/01/01の三日前を自動で出したいときどう書けばいいのかな
両方決まった形式じゃないと計算できなくて不便
20090101-3dayとかできたらいいのに

110:名無しさん＠お腹いっぱい。
09/01/19 20:21:14 TbOnLrY30
NowDate = 090101
NowDate -= 3, Days
じゃ駄目？

111:名無しさん＠お腹いっぱい。
09/01/19 20:26:47 TbOnLrY30
と書いたけど引き算は無理なのか
足し算はいけるのになんだこの仕様

ちなみに足し算する時は20090101～のYYYYMMDDHH24MISS形式にしないと無理

112:名無しさん＠お腹いっぱい。
09/01/19 21:04:28 V0nF7IjH0
Date = 20090101
Date += -3, Days
が正解というクソ仕様ですよ

113:名無しさん＠お腹いっぱい。
09/01/19 21:30:15 Qrvr5YD20
おお、足し算でマイナス指定してやるのか
ありがとう、できたよ

114:名無しさん＠お腹いっぱい。
09/01/19 21:57:36 TbOnLrY30
なるほど
時々よく分からない仕様があるな

115:名無しさん＠お腹いっぱい。
09/01/21 20:52:27 H3grfUJE0
カーソルキーのleftを押したら、leftを押す＞leftを離す＞leftを押す　に、
rightを押したらrightを押す＞rightを離す＞rightを押す　になるスクリプトはどう書きますか

116:名無しさん＠お腹いっぱい。
09/01/21 21:06:57 JC9BnGFu0
そう作ればいいんじゃないの？

117:名無しさん＠お腹いっぱい。
09/01/22 01:33:06 MvHrhn0R0
ホームページを見てるときに、
特定の画像(文字)が画面の指定した位置に来るようにする、ってできるでしょうか？

例えば、ホームページの[目次]という文字を、
画面の上の方に来るまでブラウザを下にスクロールさせたい、
という感じなんですが。

ImageSearchでできそうなんですが、
スクロールさせつつImageSearchを使う、ってのがよく解らないんです。

118:名無しさん＠お腹いっぱい。
09/01/22 02:44:50 ZAtgnYeW0
>>117
そもそも1680x1050などの広い画面でブラウザ開いた時なんか
スクロールバーが出ないから対応できないと思うんだけど

119:名無しさん＠お腹いっぱい。
09/01/22 03:14:06 t7tkDpYz0
>>117
Loop
　{
　1スクロールさせるボタンをsend
　imagesearch
　　if 合致したら抜ける
　}

でできそうな気がする

120:名無しさん＠お腹いっぱい。
09/01/22 09:11:04 7L/ljDtu0
DOM使う方が確実かと

121:名無しさん＠お腹いっぱい。
09/01/23 18:33:08 33n/xRQ70
使っているPCの、物理メモリ容量について質問です。

はやらせるページ管理人氏の　GetMemoryState(0,1)　を使わせてもらいました。
物理メモリが2GB以内なら問題ないのですが、2GB以上積んでると、
戻り値が2GBちょっとで頭打ちになり、それ以上増えないようです。

タスクマネージャや、コンピュータのプロパティで表示される物理メモリ容量の、
うまい取得方法は無いでしょうか。

122:名無しさん＠お腹いっぱい。
09/01/23 19:58:19 WXMb4uvA0
URLﾘﾝｸ(msdn.microsoft.com)
> Intel x86 プロセッサを採用し、2GB を超え、4GB 未満のメモリを実装したコンピュータでは、
> GlobalMemoryStatus 関数は MEMORYSTATUS 構造体の dwTotalPhys メンバに常に 2GB という値を返します。
> 同様に、実際の利用可能なメモリが 2～4GB の場合、MEMORYSTATUS 構造体の dwAvailPhys メンバは
> 切り捨てられて 2GB になります。

GlobalMemoryStatusExにすればいいんじゃないかな

123:名無しさん＠お腹いっぱい。
09/01/24 00:49:51 GQFssSOI0
iTunesでXButton2を押すと次の曲に移ってしますので、それを無効にしたいと考えているのですが、

#IfWinActive,iTunes ahk_class iTunes
XButton2::return

とやっても

#InstallMouseHook

を追加してもやはり制御しきれません。
何か方法はありませんでしょうか？

124:名無しさん＠お腹いっぱい。
09/01/24 10:47:12 EIN0jwLq0
使ってないからわからんが、タイトル(Class)の指定はそれで合ってるのか？

125:名無しさん＠お腹いっぱい。
09/01/24 15:42:42 EIN0jwLq0
AHKの標準出力について

-- StdOut.ahk -----------
FileAppend, OutPut test,*
exitapp
-------------------------

AutoHotkey.exe StdOut.ahk > aaa.txt
リダイレクト取込みしてやるとちゃんと出力されてるのに

AutoHotkey.exe StdOut.ahk
ってプロンプトから実行しても画面に文字が表示されないのはなんでなんだろ？

126:名無しさん＠お腹いっぱい。
09/01/24 15:58:16 dQDuGK7i0
>>125
仕様らしい。ダミーでパイプをかませばいいらしい。以下、公式リファレンスより

However, text sent to stdout will not appear at the command prompt it was launched from.
This can be worked around by piping a script's output to another command or program.

For example:

1) "%ProgramFiles%\AutoHotkey\AutoHotkey.exe" "My Script.ahk" |more

2) For /F "tokens=*" %L in ('""%ProgramFiles%\AutoHotkey\AutoHotkey.exe" "My Script .ahk""') do @Echo %L

127:123
09/01/24 16:06:55 jTY3HDp10
>>124
iTunesに対しての他のホットキーは効いてますし、

XButton2::Msgbox

とすると、次の曲に切り替わった上でメッセージボックスが表示されてしまうので、
おそらくウィンドウの指定は間違っていないと思うのですが・・・

128:名無しさん＠お腹いっぱい。
09/01/24 16:12:39 EIN0jwLq0
>>126
おお、出た出た。㌧ｸｽ
バッチファイル用の何かかと思ってスルーしてたけど 1) 2)ともプロンプトからでけた。

しかし　"fputs 標準出力プロンプト表示されない"　とかでググッても
StdErrはリダイレクトされないは書いてあっても
StdOutが表示されない事例は見つからなかったんだよね。
どうやったらそういう状態にできるのか逆に不思議だ。

129:名無しさん＠お腹いっぱい。
09/01/24 21:41:13 deghcbtf0
閉じるボタンを押すとタスクトレイに最小化するアプリを使ってるのですが
WinCloseでもWinKillでも終了してくれずにトレイに移動するだけです
今はSendでメニューバーにキーを送って無理矢理終了しているのですが
もっとスマートなやり方があれば教えてください

130:名無しさん＠お腹いっぱい。
09/01/24 22:59:20 v2e3ODaN0
クリップボードの内容を張り付けたかどうかを監視する方法ありませんか？
Onclipbpardchangeでコピーは監視出来るみたいですが張り付けを監視する方法がわかりません

131:名無しさん＠お腹いっぱい。
09/01/25 00:16:00 fIh3Ix950
>>127
#IfWinActive→IfWinActive

132:名無しさん＠お腹いっぱい。
09/01/25 00:22:51 fIh3Ix950
>>129
フィニを使う　URLﾘﾝｸ(www.vector.co.jp)

133:名無しさん＠お腹いっぱい。
09/01/25 00:32:19 ZG80n0++0
>>129
WinKillは、WinCloseでダメだったらProcessでKillするから、結局WinClose止まりってことだね。
Process, Closeが問題あるなら、WinKillも使わないほうがいい。
Alt+F4でもダメかな･･･

134:名無しさん＠お腹いっぱい。
09/01/25 02:22:31 tSgUCSWd0
ahkの初期実行部分で、実行してるマシンのOSを判別させてるんだけど、
Windows7で実行してみたら、PC名の変数が「WIN_VISTA」になった。

これだと本当のVISTAとWin7が判別できないね。
なんか適切な判別方法ないかな？

次ページ